Use Graphic Control As OpenGL Canvas

Category: Graphics - OpenGL

Date: 03-28-2012

Return to Index


 
'Most of the OpenGL snippets use the dialog for display, but you can just
'as easily use a control.  This example shows how to use a graphic control
'as the OpenGL canvas.
 
'Compiler Comments:
'This code is written to compile in PBWin10. To compile in PBWin9, split pt
'into pt.x and pt.y as arguments wherever the ChildWindowFromPoint() API is used.
 
'Primary Code:
'During initialization, make sure that the control handle is used
   Control Handle hdlg, %ID_Graphic To hGraphic
   hDC = GetDC(hGraphic)
 
'Also, during %WM_Size, you have kill the graphic control and add it again since it
'cannot be resized.  You also have to get a new rendering context, reinitialize
'the scene and resize the OpenGL viewport each time the dialog is resized.
      Case %WM_Size       : Control Kill hDlg, %ID_Graphic
                            Control Add Graphic, hDlg, %ID_Graphic,"",10,10,Lo(Word,CB.lParam)-20,Hi(Word,CB.lParam)-20, %WS_Child Or %WS_Visible Or %SS_Sunken Or %SS_Notify
                            Graphic Attach hDlg, %ID_Graphic
                            GetRenderContext : InitializeScene
                            ResizeScene Lo(Word, CB.lParam)-20, Hi(Word, CB.lParam)-20
                            DrawScene 0,0,0  'redraw with no rotation
 
'And finally, you need to ensure that the mouse action is over the control before
'entering manual drag mode.
      Case %WM_SetCursor
         GetCursorPos pt          'p.x and p.y are in screen coordinates
         ScreenToClient hDlg, pt  'p.x and p.y are now dialog client coordinates
         If GetDlgCtrlID(ChildWindowFromPoint( hDlg, pt )) <> %ID_Graphic Then Exit Function
 
 
 
'Compilable Example:
#Compiler PBWin 10
#Compile EXE
#Dim All
#Include "win32api.inc"
#Include "gl.inc"
#Include "glu.inc"
 
%ID_Timer = 1000 : %ID_Graphic = 1002
 
Global hDlg, hDC, hRC, hGraphic As DWord
Global scalefactor As Single
 
Function PBMain() As Long
   Dialog New Pixels, 0, "OpenGL Example",,, 320, 240,%WS_OverlappedWindow To hDlg
   Dialog Show Modal hdlg Call dlgproc
End Function
 
CallBack Function dlgproc()
   Local pt As Point
   Local XDelta, YDelta as Single
   Static SpinInWork,XLast,YLast As Long
 
   Select Case CB.Msg
      Case %WM_InitDialog : GetRenderContext
         InitializeScene
         SetTimer(hDlg, %ID_Timer, 50, %NULL)
         ScaleFactor = 1
      Case %WM_Timer      : DrawScene 1,1,0  'redraw with rotation on all 3 axes
      Case %WM_Paint      : DrawScene 0,0,0  'redraw with no rotation
      Case %WM_Size       : Control Kill hDlg, %ID_Graphic
         Control Add Graphic, hDlg, %ID_Graphic,"",10,10,Lo(Word,CB.lParam)-20,Hi(Word,CB.lParam)-20, %WS_Child Or %WS_Visible Or %SS_Sunken Or %SS_Notify
         Graphic Attach hDlg, %ID_Graphic
         GetRenderContext : InitializeScene
         ResizeScene Lo(Word, CB.lParam)-20, Hi(Word, CB.lParam)-20
         DrawScene 0,0,0  'redraw with no rotation
      Case %WM_Close      : wglmakecurrent %null, %null 'unselect rendering context
         wgldeletecontext hRC        'delete the rendering context
         releasedc hDlg, hDC         'release device context
      Case %WM_MouseWheel
         Select Case Hi(Integer,CB.wParam)
            Case > 0  : ScaleFactor = ScaleFactor + 0.1 : DrawScene 0,0,0
            Case < 0  : ScaleFactor = ScaleFactor - 0.1 : DrawScene 0,0,0
         End Select
      Case %WM_SetCursor
         GetCursorPos pt          'p.x and p.y are in screen coordinates
         ScreenToClient hDlg, pt  'p.x and p.y are now dialog client coordinates
         If GetDlgCtrlID(ChildWindowFromPoint( hDlg, pt )) <> %ID_Graphic Then Exit Function
         Select Case Hi(Word, CB.lParam)
            Case %WM_LButtonDown
               GetCursorPos pt              'pt has xy screen coordinates
               ScreenToClient hDlg, pt       'pt now has dialog client coordinates
               If pt.y < 0 Then Exit Select
               KillTimer CB.Hndl, %ID_Timer
               SpinInWork = 1
               XLast = Pt.x
               YLast = Pt.y
            Case %WM_MouseMove
               If SpinInWork Then
                  GetCursorPos pt           'pt has xy screen coordinates
                  ScreenToClient hDlg, pt    'pt now has dialog client coordinates
                  If pt.y < 0 Then Exit Select
                  XDelta = XLast - Pt.x
                  YDelta = YLast - Pt.y
                  DrawScene -YDelta, -XDelta, 0
                  XLast = pt.x
                  YLast = pt.y
               End If
            Case %WM_LButtonUp
               SetTimer(hDlg, %ID_Timer, 50, %NULL)
               SpinInWork = 0
         End Select
   End Select
End Function
 
Sub GetRenderContext
   Local pfd As PIXELFORMATDESCRIPTOR   'pixel format properties for device context
   pfd.nSize       =  SizeOf(PIXELFORMATDESCRIPTOR)
   pfd.nVersion    =  1
   pfd.dwFlags     = %pfd_draw_to_window Or %pfd_support_opengl Or %pfd_doublebuffer
   pfd.dwlayermask = %pfd_main_plane
   pfd.iPixelType  = %pfd_type_rgba
   pfd.ccolorbits  = 24
   pfd.cdepthbits  = 24
 
   Control Handle hdlg, %ID_Graphic To hGraphic
   hDC = GetDC(hGraphic)
   SetPixelFormat(hDC, ChoosePixelFormat(hDC, pfd), pfd)  'set properties of device context
   hRC = wglCreateContext (hDC)                           'get rendering context
   wglMakeCurrent hDC, hRC                                'make the RC current
End Sub
 
Sub InitializeScene
   glClearColor 0,0,0,0     'sets color to be used with glClear
   glClearDepth 1           'sets zvalue to be used with glClear
   glEnable %gl_depth_test                             'enable depth testing
   glHint %gl_perspective_correction_hint, %gl_nicest  'best quality rendering
   BuildDisplayList 1
End Sub
 
Sub ResizeScene (w As Long, h As Long)
   glViewport 0, 0, w, h               'resize viewport to match window size
   glMatrixMode %gl_projection         'select the projection matrix
   glLoadIdentity                    'reset the projection matrix
   gluPerspective 45, w/h, 0.1, 100  'set frustum using viewport aspect ratio
   glMatrixMode %gl_modelview          'select the modelview matrix
End Sub
 
Sub DrawScene (dx As Single, dy As Single, dz As Single)
   Static anglex, angley, anglez As Single
   glClear %gl_color_buffer_bit Or %gl_depth_buffer_bit  'clear buffers
   glLoadIdentity               'clear the modelview matrix
 
   gluLookAt 0,0,6,0,0,0,0,1,0
 
   glScalef scalefactor, scalefactor, scalefactor
 
   anglex = anglex + dx : glRotatef anglex, 1,0,0
   angley = angley + dy : glRotatef angley, 0,1,0
   anglez = anglez + dz : glRotatef anglez, 0,0,1
 
   glCallList 1
 
   SwapBuffers hDC              'display the buffer (image)
End Sub
 
Sub BuildDisplayList(ListNumber As Long)
   glNewList ListNumber, %gl_compile
   glBegin %GL_QUADS
   glColor3f   0.0,  1.0,  0.0         ' Set the color to green
   glVertex3f  1.0,  1.0, -1.0         ' Top right of the quad (Top)
   glVertex3f -1.0,  1.0, -1.0         ' Top left of the quad (Top)
   glVertex3f -1.0,  1.0,  1.0         ' Bottom left of the quad (Top)
   glVertex3f  1.0,  1.0,  1.0         ' Bottom right of the quad (Top)
 
   glColor3f   1.0,  0.5,  0.0         ' Set the color to orange
   glVertex3f  1.0, -1.0,  1.0         ' Top right of the quad (Bottom)
   glVertex3f -1.0, -1.0,  1.0         ' Top left of the quad (Bottom)
   glVertex3f -1.0, -1.0, -1.0         ' Bottom left of the quad (Bottom)
   glVertex3f  1.0, -1.0, -1.0         ' Bottom right of the quad (Bottom)
 
   glColor3f   1.0,  0.0,  0.0         ' Set the color to red
   glVertex3f  1.0,  1.0,  1.0         ' Top right of the quad (Front)
   glVertex3f -1.0,  1.0,  1.0         ' Top left of the quad (Front)
   glVertex3f -1.0, -1.0,  1.0         ' Bottom left of the quad (Front)
   glVertex3f  1.0, -1.0,  1.0         ' Bottom right of the quad (Front)
 
   glColor3f   1.0,  1.0,  0.0         ' Set the color to yellow
   glVertex3f  1.0, -1.0, -1.0         ' Top right of the quad (Back)
   glVertex3f -1.0, -1.0, -1.0         ' Top left of the quad (Back)
   glVertex3f -1.0,  1.0, -1.0         ' Bottom left of the quad (Back)
   glVertex3f  1.0,  1.0, -1.0         ' Bottom right of the quad (Back)
 
   glColor3f   0.0,  0.0,  1.0         ' Set the color to blue
   glVertex3f -1.0,  1.0,  1.0         ' Top right of the quad (Left)
   glVertex3f -1.0,  1.0, -1.0         ' Top left of the quad (Left)
   glVertex3f -1.0, -1.0, -1.0         ' Bottom left of the quad (Left)
   glVertex3f -1.0, -1.0,  1.0         ' Bottom right of the quad (Left)
 
   glColor3f   1.0,  0.0,  1.0         ' Set the color to violet
   glVertex3f  1.0,  1.0, -1.0         ' Top right of the quad (Right)
   glVertex3f  1.0,  1.0,  1.0         ' Top left of the quad (Right)
   glVertex3f  1.0, -1.0,  1.0         ' Bottom left of the quad (Right)
   glVertex3f  1.0, -1.0, -1.0         ' Bottom right of the quad (Right)
   glEnd
   glEndList
End Sub
 
'gbs_00584
'Date: 03-10-2012


created by gbSnippets
http://www.garybeene.com/sw/gbsnippets.htm