WalkThrough (Mouse)

Category: Graphics - OpenGL

Date: 03-28-2012

Return to Index


 
'Compilable Example:
#Compiler PBWin 9, PBWin 10
#Compile EXE
#Dim All
#Include "win32api.inc"
#Include "gl.inc"
#Include "glu.inc"
 
Global hDlg, hDC, hRC As DWord
Global rotVx, rotVy, scalefactor As Single
 
Function PBMain() As Long
   Dialog New Pixels, 0, "OpenGL Example",,, 320, 240,%WS_OverlappedWindow To hDlg
   Dialog Show Modal hdlg Call dlgproc
End Function
 
CallBack Function dlgproc()
   Local pt As Point
   Static SpinInWork,XLast,YLast As Long
 
   Select Case CB.Msg
      Case %WM_InitDialog : GetRenderContext
         InitializeScene
         ScaleFactor = 1
      Case %WM_Paint      : DrawScene rotVx,rotVy  'redraw with no rotation
      Case %WM_Size       : ResizeScene Lo(Word, CB.lParam), Hi(Word, CB.lParam)
         DrawScene rotVx,rotVy  'redraw with no rotation
      Case %WM_Close      : wglmakecurrent %null, %null 'unselect rendering context
         wgldeletecontext hRC        'delete the rendering context
         releasedc hDlg, hDC         'release device context      Case %WM_MouseWheel
      Case %WM_MouseWheel
         Select Case Hi(Integer,CB.wParam)
            Case > 0  : ScaleFactor = ScaleFactor + 0.1 : DrawScene rotVx,rotVy
            Case < 0  : ScaleFactor = ScaleFactor - 0.1 : DrawScene rotVx,rotVy
         End Select
      Case %WM_SetCursor
         Select Case Hi(Word, CB.lParam)
            Case %WM_LButtonDown
               SpinInWork = 1
               GetCursorPos pt              'pt has xy screen coordinates
               ScreenToClient hDlg, pt       'pt now has dialog client coordinates
               XLast = Pt.x
               YLast = Pt.y
            Case %WM_MouseMove
               If SpinInWork Then
                  GetCursorPos pt           'pt has xy screen coordinates
                  ScreenToClient hDlg, pt    'pt now has dialog client coordinates
                  If pt.y < 0 Then Exit Select
                  rotVx = rotVx - (XLast - Pt.x)/12
                  rotVy = rotVy - (YLast - Pt.y)/12
                  DrawScene rotVx, rotVy
                  XLast = pt.x
                  YLast = pt.y
               End If
            Case %WM_LButtonUp
               SpinInWork = 0
         End Select
   End Select
End Function
 
Sub GetRenderContext
   Local pfd As PIXELFORMATDESCRIPTOR   'pixel format properties for device context
   pfd.nSize       =  SizeOf(PIXELFORMATDESCRIPTOR)
   pfd.nVersion    =  1
   pfd.dwFlags     = %pfd_draw_to_window Or %pfd_support_opengl Or %pfd_doublebuffer
   pfd.dwlayermask = %pfd_main_plane
   pfd.iPixelType  = %pfd_type_rgba
   pfd.ccolorbits  = 24
   pfd.cdepthbits  = 24
 
   hDC = GetDC(hDlg)                                      'DC for dialog
   SetPixelFormat(hDC, ChoosePixelFormat(hDC, pfd), pfd)  'set properties of device context
   hRC = wglCreateContext (hDC)                           'get rendering context
   wglMakeCurrent hDC, hRC                                'make the RC current
End Sub
 
Sub InitializeScene
   glClearColor 0,0,0,0     'sets color to be used with glClear
   glClearDepth 1           'sets zvalue to be used with glClear
 
   glDepthFunc %gl_less                                'specify how depth-buffer comparisons are made
   glEnable %gl_depth_test                             'enable depth testing
   glShadeModel %gl_smooth                             'smooth shading
   glHint %gl_perspective_correction_hint, %gl_nicest  'best quality rendering
 
   BuildCubeDisplayList(1)
End Sub
 
Sub ResizeScene (w As Long, h As Long)
   glViewport 0, 0, w, h             'resize viewport to match window size
   glMatrixMode %gl_projection       'select the projection matrix
   glLoadIdentity                    'reset the projection matrix
   gluPerspective 45, w/h, 0.1, 100  'calculate the aspect ratio of the Window
   glMatrixMode %gl_modelview        'select the modelview matrix
End Sub
 
Sub DrawScene (rX as Single, rY as Single)
 
   glClear %gl_color_buffer_bit Or %gl_depth_buffer_bit  'clear buffers
   glLoadIdentity               'clear the modelview matrix
 
   gluLookAt Cos(rX)*8, 0, Sin(rX)*8, 0,0,0,0,1,0
   glScalef scalefactor, scalefactor, scalefactor
 
   glpushMatrix
   glTranslatef -2,0,0
   glCallList 1
 
   glpopMatrix
   glTranslatef +2,0,0
   glCallList 1
 
   SwapBuffers hDC              'display the buffer (image)
End Sub
 
Sub BuildCubeDisplayList(iCube As Long)
   glNewList iCube, %gl_compile
   glBegin %GL_QUADS
   glColor3f   0.0,  1.0,  0.0         ' Set the color to green
   glVertex3f  1.0,  1.0, -1.0         ' Top right of the quad (Top)
   glVertex3f -1.0,  1.0, -1.0         ' Top left of the quad (Top)
   glVertex3f -1.0,  1.0,  1.0         ' Bottom left of the quad (Top)
   glVertex3f  1.0,  1.0,  1.0         ' Bottom right of the quad (Top)
 
   glColor3f   1.0,  0.5,  0.0         ' Set the color to orange
   glVertex3f  1.0, -1.0,  1.0         ' Top right of the quad (Bottom)
   glVertex3f -1.0, -1.0,  1.0         ' Top left of the quad (Bottom)
   glVertex3f -1.0, -1.0, -1.0         ' Bottom left of the quad (Bottom)
   glVertex3f  1.0, -1.0, -1.0         ' Bottom right of the quad (Bottom)
 
   glColor3f   1.0,  0.0,  0.0         ' Set the color to red
   glVertex3f  1.0,  1.0,  1.0         ' Top right of the quad (Front)
   glVertex3f -1.0,  1.0,  1.0         ' Top left of the quad (Front)
   glVertex3f -1.0, -1.0,  1.0         ' Bottom left of the quad (Front)
   glVertex3f  1.0, -1.0,  1.0         ' Bottom right of the quad (Front)
 
   glColor3f   1.0,  1.0,  0.0         ' Set the color to yellow
   glVertex3f  1.0, -1.0, -1.0         ' Top right of the quad (Back)
   glVertex3f -1.0, -1.0, -1.0         ' Top left of the quad (Back)
   glVertex3f -1.0,  1.0, -1.0         ' Bottom left of the quad (Back)
   glVertex3f  1.0,  1.0, -1.0         ' Bottom right of the quad (Back)
 
   glColor3f   0.0,  0.0,  1.0         ' Set the color to blue
   glVertex3f -1.0,  1.0,  1.0         ' Top right of the quad (Left)
   glVertex3f -1.0,  1.0, -1.0         ' Top left of the quad (Left)
   glVertex3f -1.0, -1.0, -1.0         ' Bottom left of the quad (Left)
   glVertex3f -1.0, -1.0,  1.0         ' Bottom right of the quad (Left)
 
   glColor3f   1.0,  0.0,  1.0         ' Set the color to violet
   glVertex3f  1.0,  1.0, -1.0         ' Top right of the quad (Right)
   glVertex3f  1.0,  1.0,  1.0         ' Top left of the quad (Right)
   glVertex3f  1.0, -1.0,  1.0         ' Bottom left of the quad (Right)
   glVertex3f  1.0, -1.0, -1.0         ' Bottom right of the quad (Right)
   glEnd
   glEndList
End Sub
 
'gbs_00593
'Date: 03-10-2012


created by gbSnippets
http://www.garybeene.com/sw/gbsnippets.htm