Replace Lines M-N

Category: Controls - Edit Controls

Date: 03-28-2012

Return to Index


 
'This code shows how to get the text of a specified line range. There is
'no GetTextRange() API, so workarounds are required.
 
'Primary Code:
'DDT method for textbox control. There is no DDT statement which will identify the
'caret position, so the %EM_GetSel message is required.
   LineNumber = 1
   Control Get Text hDlg, %IDC_TextBox To temp$
   temp$ = Parse$(temp$,$crlf, LineNumber)
 
'API method for any edit control
   LineNumber = SendMessage(hEdit, %EM_LineFromChar, -1, 0) 'current line#, zero-based
   SendMessage(hEdit, %EM_GetLine, LineNumber, StrPTR(temp$))   'get text, specified line
      
'When using API with Edit Controls, remember that line numbers and char positions
'are zero-based.  Also, character positions include $crlf at end of previous lines.
 
'Compilable Example:
#Compiler PBWin 9, PBWin 10
#Compile Exe
#Dim All
#Include "Win32API.inc"
Global hDlg, hEdit As Dword
%IDC_TextBox    = 500
%IDC_ButtonDDT  = 501
%IDC_ButtonAPI  = 502
 
Function PBMain() As Long
   Local style&
   style& = %WS_Child Or %WS_Visible Or %ES_MultiLine Or %WS_VScroll Or %ES_AutoHScroll _
      Or %WS_HScroll Or %ES_AutoVScroll Or %ES_WantReturn Or %ES_NoHideSel Or %WS_TabStop
   Dialog New Pixels, 0, "Replace Lines M-N",300,300,200,150, %WS_OverlappedWindow To hDlg
   Control Add Button, hDlg, %IDC_ButtonDDT, "Replace Lines M-N (DDT)",20,10,160,20
   Control Add Button, hDlg, %IDC_ButtonAPI, "Replace Lines M-N (API)",20,40,160,20
   Control Add TextBox, hDlg, %IDC_TextBox, "Hello World"+$crlf+"Waiting ..."+$CrLf+"Goodbye World",20,70,160,80, style&, %WS_Ex_ClientEdge
   Control Handle hDlg, %IDC_TextBox To hEdit
   Dialog Show Modal hDlg Call DlgProc
End Function
 
CallBack Function DlgProc() As Long
   Local CharsReceived,LineNumber,LineNumberM,LineNumberN,StartChar,EndChar,TextLength,LineIndex,LengthLine As Long, temp$, result$
   Select Case Cb.Msg
      Case %WM_Command
         Select Case Cb.Ctl
            Case %IDC_ButtonDDT
               'DDT method
               LineNumberM = 1   'starting line number, one-based
               LineNumberN = 2   'ending line number, one-based
               Control Get Text hDlg, %IDC_TextBox To temp$
               For LineNumber = LineNumberM To LineNumberN
                  result$ = result$ + $CrLf + Parse$(temp$, $CrLf, LineNumber)
               Next LineNumber
               result$ = Mid$(result$,3)   'remove leftmost $crlf
               ? result$
            Case %IDC_ButtonAPI
               'API method
               LineNumberM = 0   'starting line number, zero-based
               LineNumberN = 1   'ending line number, zero-based
               StartChar  = SendMessage(hEdit, %EM_LineIndex, LineNumberM, 0) '1st char in LineNumberM
               EndChar    = SendMessage(hEdit, %EM_LineIndex, LineNumberN, 0) '1st char in LineNumberN
               EndChar    = EndChar + SendMessage(hEdit, %EM_LineLength, EndChar, 0) - 1  'last char in LineNumberN
               'get all text
               TextLength = SendMessage(hEdit, %WM_GetTextLength, 0, 0)+1  '+1 to cover terminating Chr$(0)
               temp$ = Space$(TextLength)
               CharsReceived = SendMessage(hEdit, %WM_GetText, TextLength, StrPtr(temp$))  'temp$ has all text
               'get startchar-endchar
               temp$ = Mid$(temp$,StartChar+1,EndChar-StartChar+1)  'temp$ now has text from Lines M-N
               ? temp$
         End Select
   End Select
End Function 
 
'gbs_01081
'Date: 03-10-2012


created by gbSnippets
http://www.garybeene.com/sw/gbsnippets.htm