Toolbar - Gray Button vs Disable Button

Date: 02-16-2022

Return to Index

 
'Compilable Example:  (Jose Includes)
#Compiler PBWin 10
#Compile EXE "gbjournal.exe"
#Dim All
%Unicode=1
#Include "win32api.inc"
#Resource Icon, bluesave, "bluesave.ico"
#Resource Icon, graysave, "graysave.ico"
 
%IDC_Toolbar    = 501
%IDC_Gray       = 502
%IDC_Disable    = 503
%IDT_SaveA      = 504
%IDT_SaveB      = 505
 
Global hDlg,hToolbar,hImageList As Dword, GrayState, DisabledState As Long
 
Function PBMain() As Long
   Dialog New Pixels, 0, "Toolbar Test",300,300,400,300, %WS_OverlappedWindow To hDlg
   Control Add Button, hDlg, %IDC_Gray, "Gray", 10,60,50,25
   Control Add Button, hDlg, %IDC_Disable, "Disable", 70,60,50,25
   CreateToolbar
   Dialog Show Modal hDlg Call DlgProc
End Function
 
CallBack Function DlgProc() As Long
   Select Case Cb.Msg
      Case %WM_Command
         Select Case Cb.Ctl
            Case %IDC_Gray
               GrayState = GrayState Xor 1
               Toolbar Delete Button hDlg, %IDC_Toolbar, ByCmd %IDT_SaveA
               If GrayState Then
                  Toolbar Add Button  hDlg, %IDC_Toolbar, 2, %IDT_SaveA,  %TbStyle_Button, "Save" At 1
               Else
                  Toolbar Add Button  hDlg, %IDC_Toolbar, 1, %IDT_SaveA,  %TbStyle_Button, "Save" At 1
               End If
 
            Case %IDC_Disable
               DisabledState = DisabledState Xor 1
               If DisabledState Then
                  Toolbar Set State hDlg, %IDC_Toolbar, ByCmd %IDT_SaveB, %TBState_Disabled
               Else
                  Toolbar Set State hDlg, %IDC_Toolbar, ByCmd %IDT_SaveB, %TBState_Enabled
               End If
         End Select
   End Select
End Function
 
Sub CreateToolbar
   'add toolbar
   Control Add Toolbar, hDlg, %IDC_Toolbar,"", 0,0,0,0
   'create imagelist
   ImageList New Icon 24,24,24,2 To hImageList
   ImageList Add Icon hImageList, "bluesave"  '1
   ImageList Add Icon hImageList, "graysave"  '2
   'attach imagelist
   Toolbar Set ImageList hDlg, %IDC_Toolbar, hImageList, 0
   'create buttons
   Toolbar Add Button    hDlg, %IDC_Toolbar, 1, %IDT_SaveA, %TbStyle_Button, "Save"
   Toolbar Add Button    hDlg, %IDC_Toolbar, 1, %IDT_SaveB, %TbStyle_Button, "Save"
End Sub
 
'gbs_00819
'Date: 03-10-2012

created by gbSnippets
http://www.garybeene.com/sw/gbsnippets.htm