Get Current Line Text

Date: 02-16-2022

Return to Index

 
'The current line is the line containing the caret. If there is a multi-line selection,
'the current line contains the 1st line of the selection,
 
'Primary Code:
'DDT method for textbox control. There is no DDT statement which will identify the
'caret position, so the %EM_GetSel message is required.
   Control Send hDlg, %IDC_TextBox, %EM_LineFromChar, -1, 0 To LineNumber  'current line#, zero-based
   Control Get Text hDlg, %IDC_TextBox To temp$
   temp$ = Parse$(temp$,$crlf,LineNumber+1
 
'API method for any edit control
   LineNumber = SendMessage(hEdit, %EM_LineFromChar, -1, 0) 'current line#, zero-based
   SendMessage(hEdit, %EM_GetLine, LineNumber, StrPTR(temp$))   'get text, specified line
      
'When using API with Edit Controls, remember that line numbers and char positions
'are zero-based.  Also, character positions include $crlf at end of previous lines.
 
'Compilable Example:  (Jose Includes)
#Compiler PBWin 9, PBWin 10
#Compile Exe
#Dim All
%Unicode=1
#Include "Win32API.inc"
Global hDlg, hEdit As Dword
%IDC_TextBox    = 500
%IDC_ButtonDDT  = 501
%IDC_ButtonAPI  = 502
 
Function PBMain() As Long
   Local style&
   style& = %WS_Child Or %WS_Visible Or %ES_MultiLine Or %WS_VScroll Or %ES_AutoHScroll _
      Or %WS_HScroll Or %ES_AutoVScroll Or %ES_WantReturn Or %ES_NoHideSel Or %WS_TabStop
   Dialog New Pixels, 0, "Get Current Line Text",300,300,200,150, %WS_OverlappedWindow To hDlg
   Control Add Button, hDlg, %IDC_ButtonDDT, "Get Current Line Text (DDT)",20,10,160,20
   Control Add Button, hDlg, %IDC_ButtonAPI, "Get Current Line Text (API)",20,40,160,20
   Control Add TextBox, hDlg, %IDC_TextBox, "Hello World"+$crlf+"Waiting ..."+$CrLf+"Goodbye World",20,70,160,80, style&, %WS_Ex_ClientEdge
   Control Handle hDlg, %IDC_TextBox To hEdit
   Dialog Show Modal hDlg Call DlgProc
End Function
 
CallBack Function DlgProc() As Long
   Local LineNumber,LineIndex,LengthLine As Long, temp$
   Select Case Cb.Msg
      Case %WM_Command
         Select Case Cb.Ctl
            Case %IDC_ButtonDDT
               'DDT method
               Control Send hDlg, %IDC_TextBox, %EM_LineFromChar, -1, 0 To LineNumber  'current line#, zero-based
               Control Get Text hDlg, %IDC_TextBox To temp$
               temp$ = Parse$(temp$, $crlf,LineNumber+1)  'Parse$ uses one-based line numbers
               ? temp$
            Case %IDC_ButtonAPI
               'API method
               LineNumber = SendMessage(hEdit, %EM_LineFromChar, -1, 0)       'current line#, zero-based
               LineIndex  = SendMessage(hEdit, %EM_LineIndex, LineNumber, 0)  '1st char in LineNumber
               LengthLine = SendMessage(hEdit, %EM_LineLength, LineIndex, 0)  'length of line containing LineIndex
               temp$ = Space$(LengthLine)
               SendMessage(hEdit, %EM_GetLine, LineNumber, StrPTR(temp$))     'get text, specified line
               ? temp$
         End Select
   End Select
End Function   
 
'gbs_00835
'Date: 03-10-2012
 

created by gbSnippets
http://www.garybeene.com/sw/gbsnippets.htm