Delete Children of Node (including sub-nodes)

Date: 02-16-2022

Return to Index

 
'Removes all children and sub-nodes of the specified node.
'The specified node is not deleted.
 
'The Windows TVM_DeleteItem message will delete a node and all
'its children, This approach cycles through all children of the
'selected node, using TVM_DeleteItem on each.
 
'The PowerBASIC DDT commands are used to loop through all
'children of the node.
 
'Primary Code - Delete Node + Children
Sub DeleteChildrenOfNode(hNode as Dword)
      Local hChild as Dword
      TreeView Get Child hDlg, %IDC_TreeView, hNode to hChild
      While hChild
         Control Send hDlg, %IDC_TreeView, %TVM_DeleteItem, 0, hChild
         TreeView Get Child hDlg, %IDC_TreeView, hNode to hChild
      Wend
End Sub
 
'Compilable Example:  (Jose Includes)
#Compiler PBWin 9, PBWin 10
#Compile EXE
#Dim All
%Unicode=1
#Include "Win32API.inc"
#Include "CommCtrl.inc"
%IDC_TreeView = 100 : %IDC_Button = 200
Global hDlg As Dword
 
Function PBMain() As Long
   Local hItem As Dword, hTemp As Dword, hTemp2 As Dword, hTemp3 As Dword
   Dialog New Pixels, 0, "TreeView",200,200,155,250, %WS_SysMenu, 0 To hDlg
   Control Add TreeView, hDlg, %IDC_TreeView, "", 10,10,130,200
   Control Add Button, hDlg, %IDC_Button,"Start", 25,220,95,20
   TreeView Insert Item hDlg, %IDC_TreeView, 0, %TVI_Last, 0,0,"Root" To hItem
   TreeView Insert Item hDlg, %IDC_TreeView, hItem, %TVI_Last, 0,0,"Mother" To hTemp
   TreeView Insert Item hDlg, %IDC_TreeView, hTemp, %TVI_Last, 0,0,"Dan" To hTemp2
   TreeView Insert Item hDlg, %IDC_TreeView, hTemp, %TVI_Last, 0,0,"Bob" To hTemp3
   TreeView Set Expanded hDlg, %IDC_TreeView, hTemp, %True
   TreeView Insert Item hDlg, %IDC_TreeView, hTemp3, %TVI_Last, 0,0,"Foot" To hTemp2
   TreeView Insert Item hDlg, %IDC_TreeView, hTemp3, %TVI_Last, 0,0,"Arm" To hTemp2
   TreeView Set Expanded hDlg, %IDC_TreeView, hTemp3, %True
   TreeView Insert Item hDlg, %IDC_TreeView, hItem, %TVI_Last, 0,0,"Father" To hTemp
   TreeView Insert Item hDlg, %IDC_TreeView, hTemp, %TVI_Last, 0,0,"Helen" To hTemp2
   TreeView Insert Item hDlg, %IDC_TreeView, hTemp, %TVI_Last, 0,0,"Any" To hTemp3
   TreeView Set Expanded hDlg, %IDC_TreeView, hTemp, %True
   TreeView Insert Item hDlg, %IDC_TreeView, hTemp3, %TVI_Last, 0,0,"Leg" To hTemp2
   TreeView Insert Item hDlg, %IDC_TreeView, hTemp3, %TVI_Last, 0,0,"Finger" To hTemp2
   TreeView Set Expanded hDlg, %IDC_TreeView, hTemp3, %True
   TreeView Set Expanded hDlg, %IDC_TreeView, hItem, %True
   Dialog Show Modal hDlg Call DlgProc
End Function
 
CallBack Function DlgProc() As Long
   Local hNode As Dword, iResult&
   If CB.Msg = %WM_Command AND CB.Ctl = %IDC_Button Then
      TreeView Get Select hDlg, %IDC_TreeView To hNode
      DeleteChildrenOfNode(hNode)
   End If
End Function
 
Sub DeleteChildrenOfNode(hNode as Dword)
   Local hChild as Dword
   TreeView Get Child hDlg, %IDC_TreeView, hNode to hChild
   While hChild
      Control Send hDlg, %IDC_TreeView, %TVM_DeleteItem, 0, hChild
      TreeView Get Child hDlg, %IDC_TreeView, hNode to hChild
   Wend
End Sub
 
'gbs_00264
'Date: 03-10-2012

created by gbSnippets
http://www.garybeene.com/sw/gbsnippets.htm