Get Selected Text in Browser

Date: 02-16-2022

Return to Index

 
'Compilable Example:  (Jose Includes)
#Compile Exe
#Dim All
%Unicode = 1
%UseWebBrowser = 1            '
#Include Once "CWindow.inc"   'Jose Roca includes
%IDC_WebBrowser  = 1001
%IDC_GetText     = 1002
 
Function PBMain
   Local hDlg As Dword, bstrURL As WString, pWindow As IWindow
   Dialog New Pixels, 0, "WebBrowser Get Selected Text", , , 600, 400, %WS_OverlappedWindow To hDlg
   Control Add Button, hDlg, %IDC_GetText, "Get Selected Text", 10,10,140,20
   pWindow = Class "CWindow"
   bstrURL = "http://www.powerbasic.com"
   pWindow.AddWebBrowserControl(hDlg, %IDC_WEBBROWSER, bstrURL, Nothing, 0, 40, 600,350)
   Dialog Show Modal hDlg, Call DlgProc
End Function
 
CallBack Function DlgProc() As Long
   Local hBrowser As Dword
   Local pIWebBrowser2 As IWebBrowser2
   Local pIHTMLDocument2 As IHTMLDocument2
   Local pIHTMLSelectionObject As IHTMLSelectionObject
   Local pDispatch As IDispatch
   Local pIHTMLTxtRange As IHTMLTxtRange
   Local temp$$
 
   Select Case CbMsg
      Case %WM_Command
         Select Case Cb.Ctl
            Case %IDC_GetText
               hBrowser = GetDlgItem(Cb.Hndl,%IDC_WebBrowser)
               pIWebBrowser2 = OC_GetDispatch(hBrowser)
               pIHTMLDocument2 = pIWebBrowser2.Document
               pIHTMLSelectionObject = pIHTMLDocument2.selection
               pIHTMLTxtRange = pIHTMLSelectionObject.createRange
               ? pIHTMLTxtRange.text
         End Select
 
      Case %WM_Size
         If Cb.WParam <> %Size_Minimized Then
            Local w,h As Long
            Dialog Get Client Cb.Hndl To w,h
            Control Set Size Cb.Hndl, %IDC_WebBrowser, w, h-40
         End If
   End Select
End Function   
 
'gbs_01323
'Date: 05-11-2013 

created by gbSnippets
http://www.garybeene.com/sw/gbsnippets.htm